Automated uninstallation of AutoCAD with VBScript

This will completely remove AutoCAD 2011 and related plug-ins.

The VBScript will detect and uninstall 32-bit or 64-bit versions of English AutoCAD 2011 and language pack.  It will also provide the option to uninstall the following plug-ins (if found):

• AutoCAD 2011 Subscription Advantage Pack
• AutoCAD WS plug-in for AutoCAD 2011
• AutoCAD 2011 VBA Enabler

If you have multiple AutoCAD 2011-based products installed, these modules may be in use by more than just AutoCAD 2011.  Do not uninstall them if they could be in use elsewhere.

The VBScript will then remove folders and registry keys related to the uninstalled product and plug-ins.

See KB: TS16077500

'============================================================================
'  Uninstall_ACAD_2011.vbs
'  This script is designed to uninstall AutoCAD 2011 and remove installed plug-ins
'
'  Copyright © 2010 by Autodesk, Inc. All Rights Reserved.                            
'
'  You are hereby granted permission to use, copy and modify this    
'  software without charge, provided you do so exclusively for       
'  your own use or for use by others in your organization in the     
'  performance of their normal duties, and provided further that     
'  the above copyright notice appears in all copies and both that    
'  copyright notice and the limited warranty and restricted rights   
'  notice below appear in all supporting documentation.              
'                                                                    
'  Incorporation of any part of this software into other software,   
'  except when such incorporation is exclusively for your own use    
'  or for use by others in your organization in the performance of   
'  their normal duties, is prohibited without the prior written      
'  consent of Autodesk, Inc.                                         
'                                                                    
'  Copying, modification and distribution of this software or any    
'  part thereof in any form except as expressly provided herein is   
'  prohibited without the prior written consent of Autodesk, Inc.    
'                                                                    
'  AUTODESK PROVIDES THIS SOFTWARE "AS IS" AND WITH ALL FAULTS.      
'  AUTODESK SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF           
'  MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  AUTODESK,       
'  INC. DOES NOT WARRANT THAT THE OPERATION OF THE SOFTWARE          
'  WILL BE UNINTERRUPTED OR ERROR FREE.                              
'                                                                    
'  Restricted Rights for US Government Users.  This software         
'  and Documentation are provided with RESTRICTED RIGHTS for US      
'  US Government users.  Use, duplication, or disclosure by the      
'  Government is subject to restrictions as set forth in FAR         
'  12.212 (Commercial Computer Software-Restricted Rights) and       
'  DFAR 227.7202 (Rights in Technical Data and Computer Software),   
'  as applicable.  Manufacturer is Autodesk, Inc., 111 McInnis       
'  Parkway, San Rafael, California 94903.                            
'
'============================================================================

Option Explicit
On Error Resume Next 

dim bProdFound, b64bitOS, bRemovePlugins
dim strInstallFolder, strProductName, strMainProductName
dim strTitle, strMsg
dim languageCode, languageAbbv
dim heroProductPrefix, heroProductSuffix
dim objShell
dim intMsgRet

dim x64products(4)
dim x86products(4)

const HKEY_CURRENT_USER = &H80000001
const HKEY_LOCAL_MACHINE = &H80000002

'============================================================================
' set the GUID prefix and suffix for the main product being uninstalled
heroProductPrefix = "{5783F2D7-9001"
heroProductSuffix = "0060B0CE6BBA}"

' set the product language code and abbreviation
' English
languageCode = "409"
languageAbbv = "enu"

'============================================================================
' initialize the arrays with the GUIDs and names for all products we may need to uninstall

' AutoCAD 2011 English (x64)
x64products(0) = heroProductPrefix & "-0" & languageCode & "-0102-" & heroProductSuffix
' AutoCAD 2011 English language pack (x64)
x64products(1) = heroProductPrefix & "-0" & languageCode & "-1102-" & heroProductSuffix
' AutoCAD 2011 Subscription Advantage Pack (x64)
x64products(2) = "{ADF5CB42-ACFD-41EF-0133-871E54505C1D}"
' AutoCAD WS plug-in for AutoCAD 2011 (x64)
x64products(3) = "{BF780694-C47E-4122-0196-B89B22F3387C}"
' AutoCAD 2011 VBA Enabler (x64)
x64products(4) = "{68519E09-4927-46AE-01E2-8D60D0CF41BC}"

' AutoCAD 2011 English (x86)
x86products(0) = heroProductPrefix & "-0" & languageCode & "-0002-" & heroProductSuffix
' AutoCAD 2011 English language pack (x86)
x86products(1) = heroProductPrefix & "-0" & languageCode & "-1002-" & heroProductSuffix
' AutoCAD 2011 Subscription Advantage Pack (x86)
x86products(2) = "{42E572CC-6D4C-4A3E-B937-7594D36B2B44}"
' AutoCAD WS plug-in for AutoCAD 2011 (x86)
x86products(3) = "{B96F1390-23DD-4002-B183-EF0560D784E9}"
' AutoCAD 2011 VBA Enabler (x86)
x86products(4) = "{ED7DFC69-2B9A-4A1F-9F50-8AB89B688EBA}"

'initialize status variants
bProdFound = False
b64bitOS = False
bRemovePlugins = False

' start by determing if we have a valid product installed
Set objShell = CreateObject("Wscript.Shell")

' look for the x64 version first
bProdFound = getProductInfo(x64products(0), False)
b64bitOS = bProdFound
' if we didn't find it, look for the x86 version
if bProdFound = False then
   bProdFound = getProductInfo(x86products(0), False)
end if

' if we found an installed product, report it and get uninstall confirmation
if bProdFound then
   strTitle = "AutoCAD 2011 Uninstall Script"
   strMainProductName = strProductName

   ' get approval to uninstall AutoCAD
   intMsgRet = uninstallACAD2011WarningMsg()
   ' if the user approved uninstall, proceed
   if intMsgRet = vbYes Then
      ' get approval to uninstall plugins
      intMsgRet = uninstallPluginsWarningMsg()

      ' if the user did not cancel the whole operation, proceed
      if intMsgRet <> vbCancel then
         if intMsgRet = vbYes Then
            bRemovePlugins = True
         end if

         if b64bitOS = True then
            uninstallProducts(x64products)
         else
            uninstallProducts(x86products)
         end if

         deleteProductFolders()    
         deleteProductRegKeys()
               
         strMsg = strMainProductName & " Uninstall Complete." & Vbcrlf & Vbcrlf & _
                  "We recommend restarting your system to help ensure complete cleanup."

         intMsgRet = msgbox(strMsg, vbOkonly+VBExclamation, strTitle)
      end if
   end  if
Else
   strMsg = "No installation of AutoCAD 2011 was found."
   intMsgRet = msgbox(strMsg, vbOkonly+VBExclamation, strTitle)
end if

'============================================================================
' uninstall each product code it finds
'============================================================================
function uninstallProducts(aProductList)
   dim pos, retVal
   dim installer : Set installer = nothing
   dim strGUID, strModuleName 
   Const msiUILevelBasic = 3         '/qb
   Const msiUILevelHideCancel = 32   '/!
   Const msiInstallStateAbsent = 2

   On Error Resume Next 
   Err.Clear

   Set installer = CreateObject("WindowsInstaller.Installer")
   installer.UILevel = msiUILevelBasic + msiUILevelHideCancel

   for pos = 0 to UBound(aProductList)
      strGUID = aProductList(pos)
      retVal = getProductInfo(strGUID, True)
      if retVal = True then
         strModuleName = strProductName
         
         if installer.productstate (strGUID) > 0 Then
            ' if the user did not approve removal of plug-ins, bail
            if pos > 1 and bRemovePlugins = False then
               Exit For
            end If
   
            'WScript.Echo "Uninstalling " & strGUID & Vbcrlf & Vbcrlf & strModuleName
   
            installer.ConfigureProduct strGUID, 65535, msiInstallStateAbsent
   
            if Err.Number <> 0 then
               WScript.Echo "Error uninstalling " & strModuleName & Vbcrlf & Vbcrlf & _
                            "Error: " & Err.Number & " - " & Err.Description
               Err.Clear
            Else
               'WScript.Echo "Uninstalled " & strModuleName
            end if
         end if
      end if
   next

   set installer = Nothing
end function

'============================================================================
' delete folders
'============================================================================
function deleteProductFolders()    
   dim pos
   dim loopCtr
   dim sUsrProfile
   dim productFolders(6)
   dim objFileSys

   On Error Resume Next        

   Set objFileSys = CreateObject("Scripting.FileSystemObject")
   'Expand Environment
   sUsrProfile = objShell.ExpandEnvironmentStrings("%UserProfile%")
   
   ' actual installation location as retrieved from registry
   productFolders(0) = strInstallFolder
   ' windows vista/win7 related AutoCAD program paths
   productFolders(1) = "C:\ProgramData\Autodesk\AutoCAD 2011\R18.1\" & languageAbbv
   productFolders(2) = sUsrProfile & "\AppData\Local\Autodesk\AutoCAD 2011\R18.1\" & languageAbbv
   productFolders(3) = sUsrProfile & "\AppData\Roaming\Autodesk\AutoCAD 2011\R18.1\" & languageAbbv
   ' windows XP related AutoCAD program paths
   productFolders(4) = sUsrProfile & "\Application Data\Autodesk\AutoCAD 2011\R18.1\" & languageAbbv
   productFolders(5) = sUsrProfile & "\Local Settings\Application Data\Autodesk\AutoCAD 2011\R18.1\" & languageAbbv
   productFolders(6) = "C:\Documents and Settings\All Users\Application Data\Autodesk\AutoCAD 2011\R18.1\" & languageAbbv

   Err.Clear

   for pos = 0 to UBound(productFolders)
      loopCtr = 0 
      ' delete the folder within a 30-second loop to account for system lock issues
      do While objFileSys.FolderExists(productFolders(pos)) And loopCtr < 6
         objFileSys.DeleteFolder productFolders(pos), True
         if Err.Number <> 0 then
            WScript.Echo "Folder not deleted: " & productFolders(pos) & Vbcrlf & Vbcrlf & _
                         "Error: " & Err.Number & " - " & Err.Description
            Err.Clear
            WScript.Sleep 5000 ' sleep 5 seconds
            loopCtr = loopCtr + 1 
         Else
            'WScript.Echo "Folder deleted: " & productFolders(pos)
         end if
      Loop 
   next

   Set objFileSys = Nothing
end function

'============================================================================
' delete registry keys for the specific installed product and language
'============================================================================
function deleteProductRegKeys()
   dim pos
   dim HKCURegKeys(3)
   dim HKLMRegKeys(3)

   HKCURegKeys(0) = "Software\Autodesk\AutoCAD\R18.1\ACAD-9001:" & languageCode
   HKCURegKeys(1) = "Software\Autodesk\AutoCAD\R18.1\AutoCAD 2011 Subscription Advantage Pack"
   HKCURegKeys(2) = "Software\Autodesk\AutoCAD\R18.1\AutoCAD 2011 VBA Enabler"
   HKCURegKeys(3) = "Software\Autodesk\AutoCAD\R18.1\AutoCAD WS plug-in for AutoCAD 2011"
   
   HKLMRegKeys(0) = "Software\Autodesk\AutoCAD\R18.1\ACAD-9001:" & languageCode
   ' the following modules are English-only so the language code is hard-coded
   HKLMRegKeys(1) = "Software\Autodesk\AutoCAD 2011 Subscription Advantage Pack:409"
   HKLMRegKeys(2) = "Software\Autodesk\AutoCAD 2011 VBA Enabler:409"
   HKLMRegKeys(3) = "Software\Autodesk\AutoCAD WS plug-in for AutoCAD 2011:409"

   ' delete the AutoCAD product reg keys
   deleteRegKey HKEY_CURRENT_USER, HKCURegKeys(0)
   deleteRegKey HKEY_LOCAL_MACHINE, HKLMRegKeys(0)
   ' delete the AutoCAD EULA reg key
   deleteRegKey HKEY_LOCAL_MACHINE, "Software\Autodesk\AutoCAD 2011 - English"

   if bRemovePlugins then
      for pos = 1 to UBound(HKCURegKeys)
         deleteRegKey HKEY_CURRENT_USER, HKCURegKeys(pos)
         deleteRegKey HKEY_LOCAL_MACHINE, HKLMRegKeys(pos)
      next
   end if
end function

'============================================================================
' delete registry key
'============================================================================
sub deleteRegKey(rootKey, delKey)
   dim strComputer, strRootKey
   dim objRegistry : set objRegistry = Nothing
   strComputer = "."
 
   On Error Resume Next 
   Err.Clear

   if rootKey = HKEY_CURRENT_USER then
      strRootKey = "HKCU\"
   else
      strRootKey = "HKLM\"
   end if

   Set objRegistry = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_
    strComputer & "\root\default:StdRegProv")

   if regKeyFound(strRootKey & delKey & "\") Then        
      objRegistry.DeleteKey rootKey, delKey
      if Err.Number <> 0 then
         WScript.Echo "DeleteKey failed: " & delKey & Vbcrlf & Vbcrlf & _
                      "Error: " & Err.Number & " - " & Err.Description
         Err.Clear
      else
         'Wscript.Echo "Deleted: " & strRootKey & delKey
      End If
   Else
      'WScript.Echo "Key not found: " & strRootKey & delKey    
   End If

   Set objRegistry = Nothing
end sub

'============================================================================
' search for installed product and get the installation folder and name
'============================================================================
function getProductInfo(prodCode, bNameOnly)
   dim strKeyPath, strValueName, strComputer
   dim objRegistry : set objRegistry = Nothing
   strComputer = "."
 
   Set objRegistry = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_
    strComputer & "\root\default:StdRegProv")
    
   strKeyPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" & prodCode

   ' determine if the product is installed
   if regKeyFound("HKLM\" & strKeyPath & "\") Then        
      ' Get the name of the product being uninstalled
      strValueName = "DisplayName"
      objRegistry.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath, strValueName, strProductName

      if bNameOnly = False then
         strKeyPath = "SOFTWARE\Autodesk\AutoCAD\R18.1\ACAD-9001:" & languageCode
      
         if regKeyFound("HKLM\" & strKeyPath & "\") Then        
            ' Get the actual installation location before uninstalling
            strValueName = "AcadLocation"
            objRegistry.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath, strValueName, strInstallFolder
         End If
      end if

      getProductInfo = True    
   Else
      getProductInfo = False
   End If

   Set objRegistry = Nothing
end function

'============================================================================
' returns true if a registry key exists
'============================================================================
function regKeyFound(regkey)
   Dim retVal
   On Error Resume Next    
   Err.Clear
   retVal = objShell.RegRead(regkey)    
   if Err.Number <> 0 then
      'WScript.Echo "Error reading key: " & regkey & Vbcrlf & Vbcrlf & _
      '             "Error: " & hex(Err.Number) & " - " & Err.Description
      Err.Clear
      regKeyFound = False
   else
      regKeyFound = True    
   End If
end function

'============================================================================
' display the initial warning message and get OK to continue
'============================================================================
function uninstallACAD2011WarningMsg()
   dim strMsg

   strMsg = "WARNING!" & Vbcrlf & Vbcrlf & _
            strMainProductName & " is currently installed at" & Vbcrlf & _
            strInstallFolder & Vbcrlf & Vbcrlf & _
            "This script will remove " & strMainProductName & " and related folders and registry keys from your computer." & Vbcrlf & Vbcrlf & _
            "This script should be run an as Administrator and we strongly recommend backing up any custom files before proceeding." & Vbcrlf & Vbcrlf & _
            "Do you want to continue?"
   
   uninstallACAD2011WarningMsg = msgbox(strMsg, vbYesNo+VBExclamation, strTitle)
end function

'============================================================================
' get the OK to uninstall plug-ins
'============================================================================
function uninstallPluginsWarningMsg()
   dim strMsg

   strMsg = "This script can also remove the VBA Enabler," & Vbcrlf & _
            "Subscription Advantage Pack, and WS Plug-in." & Vbcrlf & Vbcrlf & _
            "These modules should NOT be uninstalled if they" & Vbcrlf & _
            "are shared by another AutoCAD installation." & Vbcrlf & Vbcrlf & _
            "Do you want to uninstall these modules?"

   uninstallPluginsWarningMsg = msgbox(strMsg, vbYesNoCancel+VBExclamation, strTitle)
end function

The AutoCAD Network Administrator's Bible, 2011 Edition

David M. Stein that wrote the great Visual LISP Developer's Bible has put together The AutoCAD Network Administrator's Bible, 2011 Edition. Both available for Kindle devices and Kindle Reader apps (no Kindle needed, just the free Kindle for PC App).

Building AutoCAD 2011 network deployments, configuring folder and share permissions, customizing deployments, packaging tips, scripting tips, FlexLM and FlexNet Manager issues, including Single, Redundant, and Distributed server models, deployment using Microsoft System Center Configuration Manager 2007 R2, utilities for diagnostics and deployment management, troubleshooting tips and more! See also this Book Sample in PDF format.

You can get it on Amazon and I have no doubt that it can be worth it as David has a lot of experience deploying AutoCAD in a large enterprise.

Via Skatterbrainz Blog.

For more Learning Resources.

Autodesk University Virtual 2010

Right now I’m attending AU Virtual 2010 where the General Session keynote is running.

Here’s how we might be able to access space with the help of a microwave beam at 140 GHz.

More at Escape Dynamics

Inventor Fusion will be shipped along with AutoCAD for free. Via Deelip.com.

Factory Layout Optimization for AutoCAD is free to try via Autodesk Labs.

Factory Layout Optimization for AutoCAD Tech Preview

BIM

Autodesk TinkerBox seems like a fun game for iPad\iPhone\iPod that soon will be released.

Tinkerbox is an app that will be available for iPhone, iPod and iPad that is designed to bring engineering challenges and education to users of all ages in a 'game' like environment. There are various challenges, each one getting slightly tougher where users have to solve engineering problems like getting ball-bearings from one point to another using motors, plates, fasteners, rope, chains, conveyors etc. The intuitive interface allows you to drag and drop components from your toolbox into the working area to build a process. If you're not sure what something is or how it works, just use the interactive help to learn more about a motor for example. Via Autodesk Manufacturing Blog.

Autodesk TinkerBox

Autodesk Product Support Severity Levels and Response Times

I found these changes that will start soon and I think it will be a good thing for both customers and Autodesk.

To better address customer issues, Autodesk will begin classifying product support requests according to severity level (standard, urgent, or critical) and will provide customers with new estimated response times based on severity level and Subscription tier (Subscription, Gold, or Platinum).  Beginning December 5, 2010, customers will need to assign severity levels to each support request they submit.

In addition, Autodesk has made improvements to self-help support to ensure that customers receive predictable, and in some cases faster, responses to all support issues.  These resources include Autodesk forums and on-line Support Knowledge Centers.

* "Business hours" are defined as the local weekly hours of operation for the assigned Autodesk product support call center, in the customer's region, excluding Autodesk holidays, weekends and other non-work days applicable to the region.

** "Extended hours" are defines as 24 hours per day, seven days per week (Monday through Sunday), 365 days per year, including after-hours periods and Autodesk holidays worldwide.

How is Severity Level Determined?

1/Critical
A catastrophic defect, such as total software failure resulting in unrecoverable data loss or interruption of crucial project.  No immediate workaround is available.

• Product defect that completely stops all progress on a mission critical project
• An operation crashes the software while performing an established workflow
• An operation has corrupted project files
• After software upgrade, a previously working feature is no longer working and is seriously impeding workflow
• After software installation or upgrade, files can no longer be opened

2/Urgent
A problem or issue that severely impairs a major product function.  Operations can continue in a restricted fashion, but with effects on long-term productivity.

• A specific file will not open
• A feature will not work in one file, but works in other files
• Certain machines crash or otherwise fail to open or run a product, but other machines function normally
• An expected workflow cannot be used; an alternate method is available but not optimum

3/Standard
A problem or issue with limited effects on operation and productivity.  Workarounds may be available.

• How-to questions
• Documentation questions
• Customer suggestions
• Request for new product features or enhancements

---

Via Autodesk’s KB TS16014725

Windows Live Writer 2011 bug and wish

If adding the picture Width and Height controls to Quick Access Toolbar they work until Live Writer is restarted. After that the max value they can hold is 100 and notice also that they incorrectly show one decimal.

I wish for the ability to reorder controls on the Quick Access Toolbar something that can be done in for example Word and Excel.

See also:

Windows Live Writer 2011 beta and IE9 beta test

Open old posts in Windows Live Writer

Windows Live Writer 2011 reviewed

AutoCAD Ironman

The next release of AutoCAD is in development & codenamed "Ironman".  More details on getting involved in the pre-release beta program soon.

All Autodesk beta programs are run from http://beta.autodesk.com where you need to sign up to be able to participate. If the AutoCAD naming is the same as previous years the next release will be AutoCAD 2012.

Via Between the Lines

Autodesk Design Suite

Check out the Design Suite page and the video there. Autodesk Design Suite is a bundle of AutoCAD, Alias Sketch for AutoCAD, 3ds Max Design, Autodesk Showcase and Alias Design.

See also previous post: Autodesk Design Suits bundles

Slow Sheet Set Manager solution

If you suddenly get performance problem with a Sheet Set that previously did work good the problem might be related to that any of the paths or files points to a location that does not exists or have been moved. Check all paths and make sure they exists. Remember to check also paths to templates and so on.

To some extent SSMPropEditor can help but if you need to find all paths saved in the DST file you can open the DST file in SSMPropEditor and you will find a temporary XML file created in the %TEMP% folder that you can open in a text editor or XML editor and review. But if you want to make changes to it and save back to DST you will need our DST Converter.

The DST converter is useful for IT or CAD Managers to correct performance problems with SSM Sheet Sets that started to perform badly. The program converts a DST file to an XML file that can be edited in an XML editor or Notepad and then converted back to DST. One customer used it to replace some dead paths in an SSM file and made a 50 sheet set of construction dwgs each open in 20 seconds instead of the 1½-2 minutes it was taking. Another customer found that the size of the DST was increasing more than reasonable and was able to manually compress and remove erroneous data. Eventually found out that changing the "include in publish" status was what caused the bloat. 1 license of DST Converter is 5 EUR. Contact us for details.

Vuuch 3.5 Launched

Vuuch 3.5 Launched
Enterprise Social System for Manufacturers
Updated with Advanced New Features

Wayland, MA, November 2, 2010 – Vuuch, creator of the first enterprise social system (ESS) for manufacturers, today announced the availability of Vuuch™ 3.5. Vuuch is social technology for manufacturers of tangible products – everything from airplanes to toasters. By applying social technology to the product development process, Vuuch revolutionizes the way products are designed and manufactured. Following closely on the recent release of Vuuch 3.0, Vuuch 3.5 leverages software-as-a-service (SaaS) to respond rapidly to customer requirements. SaaS also makes it possible for customers to easily employ Vuuch, even for product development projects already under way.

“Vuuch is an enterprise social system that understands products, people and how they interact. As a result, Vuuch allows product teams to work together in ways that traditional collaborative extensions to product lifecycle management (PLM) products do not,” said Chris Williams, CEO, Vuuch. “Much of today’s existing manufacturing technology is focused on record-keeping – recording the final decisions about the design or manufacture of a product. By contrast, Vuuch is focused on the decision-making process, which helps manufacturers reap sustainable competitive advantage. With Vuuch, design, finance, production, marketing and sales decisions are made faster and more accurately than ever before.”

New and improved features in Vuuch 3.5
Import of product assemblies and parts from SolidWorks®. The Vuuch 3.5 SolidWorks plugin now allows designers to automatically populate Vuuch with the entire CAD product structure. Thereafter, the complete set of social technology features of Vuuch 3.5 are available to manage tasks, issues, discussions and the deliverables associated with the product structure.

Once imported to Vuuch 3.5, the CAD model becomes a “decision-based” bill-of-materials (BOM) that helps the product development team manage the product through all phases of its development. Each activity in Vuuch can be directly represented in the CAD model, linking the product design with all the metadata about that part and/or assembly. Vuuch maintains the representation of items in the SolidWorks model without requiring any change in CAD file management, a major convenience for users.

Custom pages. A Vuuch page represents something the team cares about and/or wants to track. In previous releases, Vuuch pages could represent Microsoft® Office® items, including Microsoft Word®, PowerPoint®, Excel® files as well as parts, products and CAD files. A “generic” Vuuch page type allowed users to represent deliverables other these. By sorting on the type of deliverable, users can quickly answer common questions like, “What Word files am I working on for this project?” “What issues are there with a specific part?” and “Who has been invited to follow this SolidWorks file?”

In Vuuch 3.5, users can now create Vuuch pages that represent anything they choose. Examples of custom pages include an engineering change order (ECO) page or a company-specific page to track a unique product feature or process. Custom page types can also be created to represent an entire product.

Each custom page takes advantage of the ESS’s full capabilities: activities can be created on that custom page, users can be dynamically invited to follow it, and it will appear in users’ lists as a new Vuuch page that can be sorted and searched. With Vuuch custom pages, the ESS’s power to represent items the team cares about is now unlimited.

Domain management and administration. Vuuch 3.5 now offers authorized users the ability to view and analyze information about Vuuch usage across their company. Once properly authorized, domain administrators may access useful statistical and analytical information including the number of Vuuch pages that have been created, the types of Vuuch pages that have been created and domain-wide usage. With domain management, Vuuch users can easily determine where problems and issues are being created and can roll up this information for reporting and analysis. It is important to remember that Vuuch domain administration does not impose a user administration burden on the domain manager, as is customary in legacy collaboration systems. Vuuch users still “friend” and “follow” Vuuch pages dynamically, using the system’s social features, all without the need for pre-defined access control lists.

New activity types. Three new activity types have been added to Vuuch pages. Info and FAQ activity types permit invited participants of the activity to develop content designed for public consumption, while limiting uninvited participants to viewing the conclusions and outcomes of that activity. In this way, social technology can be used to unite the development of content that has both public and private aspects. A Requirements activity has also been added that allows product development teams to specifically flag an activity as something that impacts the product design or manufacture.

Dashboard widgets. In Vuuch 3.5, users’ home pages have been enhanced to automatically display three sets of graphs. One of these graphs shows the number of pages the user is following by status. Another displays overdue Vuuch activities, categorizing the overdue work by the number of days it has been outstanding. The final graph displays the due dates of upcoming Vuuch activities, again categorizing them graphically by the number of days until those activities are due. Clicking any of the bars in these new graphical widgets produces a list of the selected activities, allowing users to focus on the product development tasks and issues that need their attention the most.

“One of the pressing questions manufacturers must answer is how they are going to apply technology to the product development process,” said Oleg Shilovitsky, industry analyst and blogger, BeyondPLM.com. “Vuuch offers an inventive new approach to streamline these processes, while being compatible with the investments manufacturers have already made in PLM and CAD.”

Pricing, availability and supported systems
Vuuch is available as an annual subscription. Users who create Vuuch pages require a paid license. Other users may access those pages and update those pages without a paid license. With the launch of Vuuch 3.5, the company is offering special introductory pricing of $250 per year per Vuuch page creation license.

Vuuch 3.5 is delivered as a service, so there is no installation or setup needed. The Vuuch 3.5 web UI supports major browsers, including Microsoft Internet Explorer®, Mozilla Firefox® and Google® Chrome®. Optional Vuuch add-ins allow team members to access the ESS directly from within Microsoft Office 2007, SolidWorks®, Autodesk® AutoCAD®, Autodesk Inventor® and Pro/ENGINEER®.

About Vuuch
Vuuch (www.vuuch.com), the first enterprise social system (ESS) for manufacturers, is revolutionizing the way products are developed. Vuuch’s social software is the only manufacturing-specific social technology that connects product development teams together with their deliverables, cutting time-to-market and the cost of developing products while improving quality. Founded in 2009 by a team of CAD and PLM industry veterans, Vuuch’s people-centric PLM capabilities offer manufacturers a new way to improve productivity that is compatible with existing investments in CAD, PLM and desktop applications. Vuuch is privately-held and based in Wayland, MA.

Vuuch for AutoCAD
Vuuch is also available for the AutoCAD platform via the Vuuch for AutoCAD plug-in from JTB World.